home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Cream of the Crop 1
/
Cream of the Crop 1.iso
/
EDITOR
/
AMAC44.ARJ
/
QLST@3.QM
< prev
next >
Wrap
Text File
|
1992-05-27
|
3KB
|
60 lines
* qlst@3.qm
* Macro To Load a File List of Files In Ring
* 5/18/92
*
* ----------------------------------------------------------------------
* @(3) Load File List In Ring,
* Read First File In Filelist Macro If It Exists,
* User Selects File To Load From ListFiles Prompt,
* Makes Paragraph of File List For Faster Loading
* ----------------------------------------------------------------------
* See QLSTnn.QM for this macro's description.
@3 macrobegin
setscreenoff * Turn screen off for less flicker
endfile markline begfile * Mark file list *|
* ---------------------- Copy File List To Nul ----------------------* *|a
editfile "Nul" return * Load Nul for faster loading *|
copyblock unmarkblock * Copy file list to Nul *|
* ------------ Makes File List Paragraph For Fast Loading ------------*
LOOP:
endline begline * Test if empty line
jtrue NOEMPTY
delline jtrue LOOP * Delete all empty line 'til no more
NOEMPTY:
endpara * Move end of para
cursordown jtrue LOOP * Loop 'til no more empty lines
begfile * Pos to format
setrmargin "60" return * Set margin for fast load
wrappara * Format file list as para
setrmargin "80" return * Reset right margin to "80"
* ---------------------- Load File List In Ring ----------------------*
LOAD:
setscreenon setscreenoff * Turn screen on/off to see loading
markline * Mark file name at cursor
copy * Copy file name to scrap
editfile currentfilename " " * Load current file plus
paste return * last marked on list into ring
cursorup * Move up to next file in list
jtrue LOAD * Continue loading until top of list
quit * Quit formatted Nul file list
* ------------------- Load First File in Window 2 -------------------*
nextfile * Load first file in list
* ---------------- Read Macros of First File in List ----------------*
macroread * Read first file's macros if exist
currentfilename * Insert currentfilename
backspace backspace * Remove 2 letter extension
"mac" return * Replace with "mac" extension
escape escape * Removes error prompt if first
* file does not have a macro file
setscreenon * Turn on to see ListFiles' prompt
* ------------------- Select Another File To Load -------------------*
listfiles * Select file to load from list
*
* 53 bytes Mon 02-17-1992 16:17:23 (TH @f2)
* 66 bytes Mon 04-20-1992 09:28:04 (TH @f2, from RINGnn.QM)
* 77 bytes Thu 05-07-1992 10:00:47 (TH @3, added Nul *|a)